Abrufen von Attributen und Bereichen mithilfe der HTMLAgilityPack-Bibliothek

Dein Fehler hier ist es, zu versuchen, auf ein Attribut eines Childnode von dem, den du gefunden hast, zuzugreifen.

Wenn Sie node.SelectSingleNode("//div[@class='release']") aufrufen, wird das richtige div zurückgegeben, aber das Aufrufen von .Attributes gibt nur die Attribute für das div Tag selbst und nicht für die inneren HTML-Elemente zurück.

Es ist möglich, XPATH-Abfragen zu schreiben, die den Unterknoten auswählen, zB //div[@class='release']/a - siehe http://www.w3schools.com/xpath/xpath_syntax.asp für weitere Informationen zu XPATH. Obwohl die Beispiele für XML gelten, sollten die meisten Prinzipien für ein HTML-Dokument gelten.

Ein anderer Ansatz besteht darin, weitere XPATH-Aufrufe für den gefundenen Knoten zu verwenden. Ich habe Ihren Code so geändert, dass er mit diesem Ansatz funktioniert:

' Load the html document.
htmldoc.LoadHtml(IO.File.ReadAllText("C:\source.html"))

' Select the (10 items) nodes.
htmlnodes = htmldoc.DocumentNode.SelectNodes("//div[@class='item']")

' Loop through the nodes.
For Each node As HtmlAgilityPack.HtmlNode In htmlnodes

    Dim releaseNode = node.SelectSingleNode(".//div[@class='release']")
    'Assumes we find the node and it has a a-tag
    Title = releaseNode.SelectSingleNode(".//a").Attributes("title").Value
    URL = releaseNode.SelectSingleNode(".//a").Attributes("href").Value

    Dim thumbNode = node.SelectSingleNode(".//div[@class='thumb']")
    Cover = thumbNode.SelectSingleNode(".//img").Attributes("src").Value

    Dim releaseYearNode = node.SelectSingleNode(".//div[@class='release-year']")
    Year = CInt(releaseYearNode.SelectSingleNode(".//span").InnerText)

    Dim genreNode = node.SelectSingleNode(".//div[@class='genre']")
    Dim genreLinks = genreNode.SelectNodes(".//a")
    Genres = (From n In genreLinks Select n.InnerText).ToArray()

    Console.WriteLine("Title : {0}", Title)
    Console.WriteLine("Cover : {0}", Cover)
    Console.WriteLine("Year  : {0}", Year)
    Console.WriteLine("Genres: {0}", String.Join(",", Genres))
    Console.WriteLine("URL   : {0}", URL)

Next

Beachten Sie, dass in diesem Code angenommen wird, dass das Dokument korrekt erstellt wurde und dass jeder Knoten / jedes Element / Attribut existiert und korrekt ist. Vielleicht möchten Sie dazu eine Menge Fehler hinzufügen, zB If someNode Is Nothing Then ....

Edit: Ich habe den Code oben leicht geändert, um sicherzustellen, dass jeder .SelectSingleNode das "./" Präfix verwendet - das stellt sicher, dass es funktioniert, wenn es mehrere "Element" -Knoten gibt, andernfalls wählt es die erste Übereinstimmung aus dem Dokument nicht die aktuelle Knoten.

Wenn Sie eine kürzere XPATH-Lösung wünschen, ist hier der gleiche Code, der diesen Ansatz verwendet:

' Load the html document.
htmldoc.LoadHtml(IO.File.ReadAllText("C:\source.html"))

' Select the (10 items) nodes.
htmlnodes = htmldoc.DocumentNode.SelectNodes("//div[@class='item']")

' Loop through the nodes.
For Each node As HtmlAgilityPack.HtmlNode In htmlnodes

    Title = node.SelectSingleNode(".//div[@class='release']/h4/a[@title]").Attributes("title").Value
    URL = node.SelectSingleNode(".//div[@class='release']/h4/a[@href]").Attributes("href").Value

    Cover = node.SelectSingleNode(".//div[@class='thumb']/a/img[@src]").Attributes("src").Value

    Year = CInt(node.SelectSingleNode(".//div[@class='release-year']/span").InnerText)

    Dim genreLinks = node.SelectNodes(".//div[@class='genre']/a")
    Genres = (From n In genreLinks Select n.InnerText).ToArray()

    Console.WriteLine("Title : {0}", Title)
    Console.WriteLine("Cover : {0}", Cover)
    Console.WriteLine("Year  : {0}", Year)
    Console.WriteLine("Genres: {0}", String.Join(",", Genres))
    Console.WriteLine("URL   : {0}", URL)
    Console.WriteLine()

Next