XPath "seguenti fratelli prima"

html-agility-pack xpath

Domanda

Sto provando a selezionare gli elementi (a) con XPath 1.0 (o possibilmente potrebbe essere con Regex) che seguono i fratelli di particolare elemento (b) ma precedono solo un altro elemento b.

<img><b>First</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/first-href">First Href</a> - 19:30<br>
<img><b>Second</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/second-href">Second Href</a> - 19:30<br>
<img>&nbsp;&nbsp;<a href="/third-href">Third Href</a> - 19:30<br>

Ho cercato di rendere il campione il più vicino possibile al mondo reale. Quindi, in questo scenario, quando sono all'elemento

<b>First</b>

Devo selezionare

<a href="/first-href">First Href</a> 

e quando sono a

<b>Second</b> 

Devo selezionare

<a href="/second-href">Second Href</a> 
<a href="/third-href">Third Href</a>

Qualche idea su come ottenerlo? Grazie!

Risposta accettata

Crea dinamicamente questo XPath:

following-sibling::a[preceding-sibling::b[1][.='xxxx']]

dove 'xxxx' è sostituito con il testo dell'attuale <b> .

Questo presuppone che tutti gli elementi siano effettivamente fratelli. Se non lo sono, puoi provare a lavorare con gli assi preceding e following , o scrivere un XPath più specifico che assomigli meglio alla struttura del documento.

In XSLT puoi anche usare:

following-sibling::a[
  generate-id(preceding-sibling::b[1]) = generate-id(current())
]

Risposta popolare

Ecco una soluzione che è solo una singola espressione XPath .

Utilizzando la formula di Kaysian per l'intersezione di due nodesets $ns1 e $ns2 :

  $ns1[count(. | $ns2) = count($ns2)]

Semplicemente sostituiamo $ns1 con il nodeset di <a> fratelli che seguono il nodo <b> corrente e sostituiamo $ns2 con il nodeset di <a> fratelli che precedono il prossimo nodo <b> .

Ecco una trasformazione completa che utilizza questo :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="/">
   <xsl:apply-templates select="*/b"/>
  </xsl:template>

  <xsl:template match="b">
    At: <xsl:value-of select="."/>

    <xsl:variable name="vNextB" select="following-sibling::b[1]"/>

    <xsl:variable name="vA-sAfterCurrentB" select="following-sibling::a"/>

    <xsl:variable name="vA-sBeforeNextB" select=
    "$vNextB/preceding-sibling::a
    |
     $vA-sAfterCurrentB[not($vNextB)]
    "/>

    <xsl:copy-of select=
     "$vA-sAfterCurrentB
              [count(.| $vA-sBeforeNextB)
              =
               count($vA-sBeforeNextB)
               ]
    "/>
  </xsl:template>
</xsl:stylesheet>

Quando questa trasformazione viene applicata al seguente documento XML :

<t>
    <img/>
    <b>First</b>
    <br />&#xA0;&#xA0;
    <img/>&#xA0;&#xA0;
    <a href="/first-href">First Href</a> - 19:30
    <br />
    <img/>
    <b>Second</b>
    <br />
    <img/>&#xA0;&#xA0;
    <a href="/second-href">Second Href</a> - 19:30
    <br />
    <img/>&#xA0;
    <a href="/third-href">Third Href</a> - 19:30
    <br />
</t>

il risultato corretto è prodotto :

   At: First <a href="/first-href">First Href</a>
    At: Second <a href="/second-href">Second Href</a>
<a href="/third-href">Third Href</a>


Autorizzato sotto: CC-BY-SA with attribution
Non affiliato con Stack Overflow
È legale questo KB? Sì, impara il perché
Autorizzato sotto: CC-BY-SA with attribution
Non affiliato con Stack Overflow
È legale questo KB? Sì, impara il perché