XPath "после братьев и сестер до"

html-agility-pack xpath

Вопрос

Я пытаюсь выбрать элементы (a) с XPath 1.0 (или, возможно, с Regex), которые следуют за братьями и сестрами конкретного элемента (b), но только предшествуют другому элементу b.

<img><b>First</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/first-href">First Href</a> - 19:30<br>
<img><b>Second</b><br>&nbsp;&nbsp;
<img>&nbsp;&nbsp;<a href="/second-href">Second Href</a> - 19:30<br>
<img>&nbsp;&nbsp;<a href="/third-href">Third Href</a> - 19:30<br>

Я попытался сделать образец максимально приближенным к реальному миру. Поэтому в этом случае, когда я нахожусь в элементе

<b>First</b>

Мне нужно выбрать

<a href="/first-href">First Href</a> 

и когда я нахожусь

<b>Second</b> 

Мне нужно выбрать

<a href="/second-href">Second Href</a> 
<a href="/third-href">Third Href</a>

Любая идея, как этого достичь? Спасибо!

Принятый ответ

Динамически создайте этот XPath:

following-sibling::a[preceding-sibling::b[1][.='xxxx']]

где «xxxx» заменяется текстом текущего <b> .

Это предполагает, что все элементы на самом деле являются братьями и сестрами. Если это не так, вы можете попробовать работать с preceding и following осями или написать более конкретный XPath, который лучше напоминает структуру документа.

В XSLT вы также можете использовать:

following-sibling::a[
  generate-id(preceding-sibling::b[1]) = generate-id(current())
]

Популярные ответы

Вот решение, которое представляет собой всего лишь одно выражение XPath .

Используя формулу Кайсиана для пересечения двух узлов $ns1 и $ns2 :

  $ns1[count(. | $ns2) = count($ns2)]

Мы просто подставляем $ns1 узлов <a> siblings, которые следуют за текущим узлом <b> , и мы подставляем $ns2 набором узлов <a> siblings, которые предшествуют следующему узлу <b> .

Вот полное преобразование, которое использует это :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="/">
   <xsl:apply-templates select="*/b"/>
  </xsl:template>

  <xsl:template match="b">
    At: <xsl:value-of select="."/>

    <xsl:variable name="vNextB" select="following-sibling::b[1]"/>

    <xsl:variable name="vA-sAfterCurrentB" select="following-sibling::a"/>

    <xsl:variable name="vA-sBeforeNextB" select=
    "$vNextB/preceding-sibling::a
    |
     $vA-sAfterCurrentB[not($vNextB)]
    "/>

    <xsl:copy-of select=
     "$vA-sAfterCurrentB
              [count(.| $vA-sBeforeNextB)
              =
               count($vA-sBeforeNextB)
               ]
    "/>
  </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к следующему XML-документу :

<t>
    <img/>
    <b>First</b>
    <br />&#xA0;&#xA0;
    <img/>&#xA0;&#xA0;
    <a href="/first-href">First Href</a> - 19:30
    <br />
    <img/>
    <b>Second</b>
    <br />
    <img/>&#xA0;&#xA0;
    <a href="/second-href">Second Href</a> - 19:30
    <br />
    <img/>&#xA0;
    <a href="/third-href">Third Href</a> - 19:30
    <br />
</t>

получается правильный результат :

   At: First <a href="/first-href">First Href</a>
    At: Second <a href="/second-href">Second Href</a>
<a href="/third-href">Third Href</a>


Related

Лицензировано согласно: CC-BY-SA with attribution
Не связан с Stack Overflow
Является ли этот КБ законным? Да, узнайте, почему
Лицензировано согласно: CC-BY-SA with attribution
Не связан с Stack Overflow
Является ли этот КБ законным? Да, узнайте, почему